117 lines
3.8 KiB
Plaintext
117 lines
3.8 KiB
Plaintext
#
|
||
# A simple theme that displays relevant, contextual information.
|
||
#
|
||
# Authors:
|
||
# Sorin Ionescu <sorin.ionescu@gmail.com>
|
||
#
|
||
# Screenshots:
|
||
# http://i.imgur.com/AzjmpwM.png
|
||
#
|
||
|
||
# Load dependencies.
|
||
pmodload 'helper'
|
||
|
||
function prompt_sorin_pwd {
|
||
local pwd="${PWD/#$HOME/~}"
|
||
|
||
if [[ "$pwd" == (#m)[/~] ]]; then
|
||
_prompt_sorin_pwd="$MATCH"
|
||
unset MATCH
|
||
else
|
||
_prompt_sorin_pwd="${${${${(@j:/:M)${(@s:/:)pwd}##.#?}:h}%/}//\%/%%}/${${pwd:t}//\%/%%}"
|
||
fi
|
||
}
|
||
|
||
function prompt_sorin_git_info {
|
||
# Append Git status.
|
||
if [[ -s "$_prompt_sorin_precmd_async_data" ]]; then
|
||
alias typeset='typeset -g'
|
||
source "$_prompt_sorin_precmd_async_data"
|
||
RPROMPT+='${git_info:+${(e)git_info[status]}}'
|
||
unalias typeset
|
||
fi
|
||
|
||
# Reset PID.
|
||
_prompt_sorin_precmd_async_pid=0
|
||
|
||
# Redisplay prompt.
|
||
zle && zle reset-prompt
|
||
}
|
||
|
||
function prompt_sorin_precmd_async {
|
||
# Get Git repository information.
|
||
if (( $+functions[git-info] )); then
|
||
git-info
|
||
typeset -p git_info >! "$_prompt_sorin_precmd_async_data"
|
||
fi
|
||
|
||
# Signal completion to parent process.
|
||
kill -USR1 $$
|
||
}
|
||
|
||
function prompt_sorin_precmd {
|
||
setopt LOCAL_OPTIONS
|
||
unsetopt XTRACE KSH_ARRAYS
|
||
|
||
# Format PWD.
|
||
prompt_sorin_pwd
|
||
|
||
# Define prompts.
|
||
RPROMPT='${editor_info[overwrite]}%(?:: %F{red}⏎%f)${VIM:+" %B%F{green}V%f%b"}${INSIDE_EMACS:+" %B%F{green}E%f%b"}%f'
|
||
|
||
# Kill the old process of slow commands if it is still running.
|
||
if (( _prompt_sorin_precmd_async_pid > 0 )); then
|
||
kill -TERM "$_prompt_sorin_precmd_async_pid" &>/dev/null
|
||
fi
|
||
|
||
# Compute slow commands in the background.
|
||
trap prompt_sorin_git_info USR1
|
||
prompt_sorin_precmd_async &!
|
||
_prompt_sorin_precmd_async_pid=$!
|
||
}
|
||
|
||
function prompt_sorin_setup {
|
||
setopt LOCAL_OPTIONS
|
||
unsetopt XTRACE KSH_ARRAYS
|
||
prompt_opts=(cr percent subst)
|
||
_prompt_sorin_precmd_async_pid=0
|
||
_prompt_sorin_precmd_async_data="${TMPPREFIX}-prompt_sorin_data"
|
||
|
||
# Load required functions.
|
||
autoload -Uz add-zsh-hook
|
||
|
||
# Add hook for calling git-info before each command.
|
||
add-zsh-hook precmd prompt_sorin_precmd
|
||
|
||
# Set editor-info parameters.
|
||
zstyle ':prezto:module:editor:info:completing' format '%B%F{red}...%f%b'
|
||
zstyle ':prezto:module:editor:info:keymap:primary' format ' %B%F{red}❯%F{yellow}❯%F{green}❯%f%b'
|
||
zstyle ':prezto:module:editor:info:keymap:primary:overwrite' format ' %F{red}♺%f'
|
||
zstyle ':prezto:module:editor:info:keymap:alternate' format ' %B%F{green}❮%F{yellow}❮%F{red}❮%f%b'
|
||
|
||
# Set git-info parameters.
|
||
zstyle ':prezto:module:git:info' verbose 'yes'
|
||
zstyle ':prezto:module:git:info:action' format ':%%B%F{yellow}%s%f%%b'
|
||
zstyle ':prezto:module:git:info:added' format ' %%B%F{green}✚%f%%b'
|
||
zstyle ':prezto:module:git:info:ahead' format ' %%B%F{yellow}⬆%f%%b'
|
||
zstyle ':prezto:module:git:info:behind' format ' %%B%F{yellow}⬇%f%%b'
|
||
zstyle ':prezto:module:git:info:branch' format ':%F{green}%b%f'
|
||
zstyle ':prezto:module:git:info:commit' format ':%F{green}%.7c%f'
|
||
zstyle ':prezto:module:git:info:deleted' format ' %%B%F{red}✖%f%%b'
|
||
zstyle ':prezto:module:git:info:modified' format ' %%B%F{blue}✱%f%%b'
|
||
zstyle ':prezto:module:git:info:position' format ':%F{red}%p%f'
|
||
zstyle ':prezto:module:git:info:renamed' format ' %%B%F{magenta}➜%f%%b'
|
||
zstyle ':prezto:module:git:info:stashed' format ' %%B%F{cyan}✭%f%%b'
|
||
zstyle ':prezto:module:git:info:unmerged' format ' %%B%F{yellow}═%f%%b'
|
||
zstyle ':prezto:module:git:info:untracked' format ' %%B%F{white}◼%f%%b'
|
||
zstyle ':prezto:module:git:info:keys' format \
|
||
'status' '$(coalesce "%b" "%p" "%c")%s%A%B%S%a%d%m%r%U%u'
|
||
|
||
# Define prompts.
|
||
PROMPT='${SSH_TTY:+"%F{red}%n%f@%F{yellow}%m%f "}%F{cyan}${_prompt_sorin_pwd}%(!. %B%F{red}#%f%b.)${editor_info[keymap]} '
|
||
RPROMPT=''
|
||
SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
|
||
}
|
||
|
||
prompt_sorin_setup "$@"
|